Maple-Worksheet: Richtungsfeld

Richtungsfeld und Isoklinen

> restart; with(DEtools): with(plots):
interface(displayprecision = 4):

Gegeben sei eine lineare Differentialgleichung 1. Ordnung:

> DGl:= diff(y(x), x) = a*x + b*y(x): DGl;

> gl:= dsolve(DGl, y(x)): gl;

y(x) = -a/b*x-a/b^2+exp(b*x)*_C1

Umbenennen der von Maple mit "_C1" bezeichneten Konstante:

> gl:= subs(_C1 = C, gl): gl;

y(x) = -a/b*x-a/b^2+exp(b*x)*C

Lösung der Differentialgleichung DGl unter Beachtung von Randbedingungen:

> a:= 2.0: b:= 1.5:

dsolve({DGl, y(0) = 2}, y(x)):
evalf(%, 4);

Darstellung einiger Lösungen der Differentialgleichung DGl mit a = 2 und b = 1 im Richtungsfeld;
für diese Lösungen sollen die Bedingungen y(0) = -1, y(0) = 1, y(0) = 2 und y(0) = 3 gelten:

> a:= 2.0: b:= 1.5:

DEplot(DGl, y(x), x = -3..3, y = -2..3,
  {[0,-1], [0,1], [0,2], [0,3]},
  arrows = line,
thickness = 2,
  font = [Courier, 12],
  labelfont = [Courier, 14],
size = [350, 350],
  linecolor = navy);

richtungsfeld5

Hinschreiben der oben definierten Gleichung gl unter Beachtung, dass eben a = 2 und b = 1,5 gesetzt wurde:

> gl:= evalf(gl): gl;

Differenzieren der rechten Seite dieser Gleichung:

> Dy(x):= evalf(diff(rhs(gl), x), 4);

Auflösen der Gleichung Dy(x) = k nach C:

> assign(evalf(isolate(Dy(x) = k, C), 4)):

C:= C;

C := .6667*(k+1.333)/exp(1.5*x)

Einsetzen dieses Terms für C in Gleichung gl und gleichzeitiges Umbenennen von "y(x)" in "f(x)":

> f(x):= rhs(gl);

Zeichnen des Richtungsfeldes mit vier Isoklinen:

> RFeld:= DEplot(DGl, y(x), x = -6..6, y = -10..8,

  {[0,-1], [0,1], [0,2], [0,3]},
  arrows = line,
  thickness = 2,
  font = [Courier, 12],
  labelfont = [Courier, 14],
size = [350, 350],
  linecolor = navy):
Isoklinen:= plot([subs (k = -10, f(x)),
  subs(k = -1, f(x)),
  subs(k = 1, f(x)),
  subs(k = 5, f(x))],
  x = -6..6, y = -10..8,
  color = magenta,
linestyle = dashdot):
display(RFeld, Isoklinen);